#nop vim: set filetype=tt:;

/*
本文件属于 PaoTin++ 的一部分。
PaoTin++ © 2020~2023 的所有版权均由担子炮(dzp <danzipao@gmail.com>) 享有并保留一切法律权利
你可以在遵照 GPLv3 协议的基础之上使用、修改及重新分发本程序。
*/

#nop 字符串默认值;
#func {default} {
    #local value    {%1};
    #local default  {%2};

    #if { @isEmpty{$value} } {
        #return {$default};
    };

    #return {$value};
};

#nop 数值默认值;
#func {defaultNum} {
    #local value    {%1};
    #local default  {%2};

    #if { @isEmpty{$value} } {
        #return {$default};
    };

    #if { "$value" != "{-|}%+1..d{|\.\d+}" } {
        #return {$default};
    };

    #if { $value == 0 } {
        #return {$default};
    };

    #return {$value};
};

#nop 变量展开的时候，如果变量不存在会直接展开成 $var 形式的变量名自身，;
#nop 这种情况下也允许用 default 值代替;
#func {defaultVar} {
    #local value    {%1};
    #local default  {%2};

    #if { @isEmptyVar{$value} } {
        #return {$default};
    };

    #return {$value};
};

#nop 变量展开的时候，如果变量不存在会直接展开成 $var 形式的变量名自身，;
#nop 这种情况下也允许用 default 值代替;
#func {defaultNumVar} {
    #local value    {%1};
    #local default  {%2};

    #if { @isEmptyVar{$value} } {
        #return {$default};
    };

    #if { "$value" != "{-|}%+1..d{|\.\d+}" } {
        #return {$default};
    };

    #if { $value == 0 } {
        #return {$default};
    };

    #return {$value};
};

#nop 判断参数是否为空;
#func {isEmpty} {
    #local value {%0};

    #if { "$value" == "" } {
        #return 1;
    };

    #return 0;
};

#nop 判断参数是否为空，或者变量展开失败;
#func {isEmptyVar} {
    #local value {%0};

    #if { "$value" == "" } {
        #return 1;
    };

    #if { "$value" == "$%*" } {
        #return 1;
    };

    #return 0;
};