#nop vim: set filetype=tt:;

/*
本文件属于 PaoTin++ 的一部分
===========
PaoTin++ © 2020~2023 的所有版权均由担子炮(dzp <danzipao@gmail.com>) 享有并保留一切法律权利
你可以在遵照 GPLv3 协议的基础之上使用、修改及重新分发本程序。
===========
*/

#var basic_char_hp[META] {
    {NAME}      {HP 信息解析}
    {DESC}      {解析 hp 和 hpbrief 两个命令的内容，并储存到变量 char[HP]}
    {AUTHOR}    {担子炮}
    {NOTE}      {本文件属于 PaoTin++ 的一部分}
};

load-lib event;
load-lib speedo;

event.Define {char/hp}       {无参}  {$MODULE} {已经获取到 hp 命令输出结果，并更新 char[HP]。};
event.Define {char/hpbrief}  {无参}  {$MODULE} {已经获取到 hpbrief 命令输出结果，并更新 char[HP]。};
event.Define {char/hpneili}  {无参}  {$MODULE} {已经获取到 hp -neili 命令输出结果，并更新 char[HP]。};

#func {basic_char_hp.Init} {
    #class data/basic/char open;
    #var char[HP]               {};
    #var char[HP][经验]         {1};
    #var char[HP][经验显示]     {1};
    #var char[HP][潜能]         {1};
    #var char[HP][潜能显示]     {1};
    #var char[HP][上次内力]     {0};
    #var char[HP][当前内力]     {0};
    #var char[HP][最大内力]     {1};
    #var char[HP][加力]         {0};
    #var char[HP][内力百分比]   {0};
    #var char[HP][上次精力]     {0};
    #var char[HP][当前精力]     {0};
    #var char[HP][最大精力]     {1};
    #var char[HP][精力百分比]   {0};
    #var char[HP][上次气血]     {0};
    #var char[HP][当前气血]     {0};
    #var char[HP][有效气血]     {1};
    #var char[HP][最大气血]     {1};
    #var char[HP][气血百分比]   {0};
    #var char[HP][气血健康度]   {0};
    #var char[HP][上次精神]     {0};
    #var char[HP][当前精神]     {0};
    #var char[HP][有效精神]     {1};
    #var char[HP][最大精神]     {1};
    #var char[HP][精神百分比]   {0};
    #var char[HP][精神健康度]   {0};
    #var char[HP][上次真气]     {0};
    #var char[HP][当前真气]     {0};
    #var char[HP][最大真气]     {1};
    #var char[HP][真气减伤]     {0};
    #var char[HP][真元]         {0};
    #var char[HP][食物]         {0};
    #var char[HP][最大食物]     {1};
    #var char[HP][饥饿]         {};
    #var char[HP][饮水]         {0};
    #var char[HP][最大饮水]     {1};
    #var char[HP][口渴]         {};
    #var char[HP][气势]         {0};
    #var char[HP][状态]         {};
    #var char[HP][毒]           {};
    #class data/basic/char close;

    set hpbrief long,report;
    #delay {char.Init} {char.GetHP; char.GetHP2} {1};

    #return true;
};

/*
hp 有两种格式，非战斗状态：
┌───个人状态────────────┬───────────────────┐
│【精神】 5978    / 5978     [103%]    │【精力】 12102   / 6051    (+   0)    │
│【气血】 23372   / 23372    [101%]    │【内力】 5369    / 7063    (+   1)    │
│【真气】 1367    / 1367     [  9%]    │【静气】 101%               [正常]    │
│【食物】 874     / 900      [正常]    │【潜能】 7.67万                       │
│【饮水】 874     / 900      [正常]    │【经验】 1349.88万                    │
├───────────────────┴───────────────────┤
│【状态】 健康、怒、星宿火毒、星宿毒掌毒                                       │
└──────────────────────────────北大侠客行────┘
战斗状态：
*/
#alias {char.hp.parse.hp} {
    #class char-hp-parse-hp open;
    #action {^│【精神】%s%d%s/%s%d%s[%s%d\%]%!s│【精力】%s%d%s/%s%d%s(+%s%d)%!s│$} {
        #var char[HP][当前精神] {%%2};
        #var char[HP][有效精神] {%%5};
        #var char[HP][当前精力] {%%10};
        #var char[HP][最大精力] {%%13};
        speedo.Set {当前精神} {$char[HP][当前精神]} {true} {10};
        speedo.Set {当前精力} {$char[HP][当前精力]} {true} {10};
    };
    #action {^│【气血】%s%d%s/%s%d%s[%s%d\%]%!s│【内力】%s%d%s/%s%d%s(+%s%d)%!s│$} {
        #var char[HP][当前气血] {%%2};
        #var char[HP][有效气血] {%%5};
        #var char[HP][当前内力] {%%10};
        #var char[HP][最大内力] {%%13};
        #var char[HP][加力]     {%%16};
        speedo.Set {当前气血} {$char[HP][当前气血]} {true} {10};
        speedo.Set {当前内力} {$char[HP][当前内力]} {true} {10};
    };
    #action {^│【真气】%!s%d%!s/%!s%d%!s[%!s%d\%]%!s│【%!*】%!s%!d\%%!s[%!*]%!s│$} {
        #var char[HP][当前真气] {%%1};
        #var char[HP][最大真气] {%%2};
        #var char[HP][真气减伤] {%%3};
        speedo.Set {当前真气} {$char[HP][当前真气]} {true} {10};
    };
    #action {^│【食物】%s%d%s/%s%d%s[%S]%!s│【潜能】%s%S%!s│$} {
        #var char[HP][食物]     {%%2};
        #var char[HP][最大食物] {%%5};
        #var char[HP][饥饿]     {%%7};
        #var char[HP][潜能显示] {%%9};
        speedo.Set {食物} {$char[HP][食物]} {true} {10};
    };
    #action {^│【饮水】%s%d%s/%s%d%s[%S]%!s│【经验】%s%S%!s│$} {
        #var char[HP][饮水]     {%%2};
        #var char[HP][最大饮水] {%%5};
        #var char[HP][口渴]     {%%7};
        #var char[HP][经验显示] {%%9};
        speedo.Set {饮水} {$char[HP][饮水]} {true} {10};
    };
    #action {^│【气势】%s%d%s\%%s　【平衡】%s%d%s\%%!s│$} {
        #var char[HP][气势]     {%%2};
    };
    #action {^├───────────────────────────────────┤$} {
        #nop;
    };
    #action {~【状态】%*│} {
        #local status {%%1};
        #replace status { } {};
        #replace status {{\033\[[0-9;]+m}} {};
        #replace status {、} {;};
        #var char[HP][状态] {$status};
        #local item {};
        #local poison {};
        #foreach {$status} {item} {
            #if { "$item" == "{.*毒|火焰刀焚伤|生死符}" } {
                #local poison {$poison$item;};
            };
        };
        #replace poison {;$} {};
        #var char[HP][毒] {$poison};
    };

    #action {@re.TableTail{char/hp}} {
        #math char[HP][气血百分比] { $char[HP][当前气血] * 100 / $char[HP][最大气血] };
        #math char[HP][精神百分比] { $char[HP][当前精神] * 100 / $char[HP][最大精神] };
        #math char[HP][内力百分比] { $char[HP][当前内力] * 50  / $char[HP][最大内力] };
        #math char[HP][精力百分比] { $char[HP][当前精力] * 50  / $char[HP][最大精力] };
        #math char[HP][气血健康度] { $char[HP][有效气血] * 100 / $char[HP][最大气血] };
        #math char[HP][精神健康度] { $char[HP][有效精神] * 100 / $char[HP][最大精神] };
        event.Emit char/hp;
        char.hp.parse.done;
    };

    #alias {char.hp.parse.done} {
        #class char-hp-parse-hp kill;
        #class char.GetHP kill;
    };

    event.ClassHandleOnce GA {char.hp} {char} {
        char.hp.parse.done;
        #nop 吞参数专用，不要删除本行，也不要在末尾加分号或是别的语句
    };

    #class char-hp-parse-hp close;
};

/*
hp -neili 格式：
2024-03-26 12:13:46 INPUT: hp -neili（无内功）
╭───内功信息────────────────────────────────╮
│暂无                                                                          │
├───其他信息────────────┬───────────────────┤
│【走火入魔】 0.00%                    │【极限内力】 0                        │
│【恢复效率】 0.00%                    │【精纯程度】 0.00%                    │
│【压缩内力】 无                       │【内视加成】 无                       │
╰───────────────────┴──────────北大侠客行────╯
2024-03-26 12:14:53 INPUT: hp -neili（单一内功）
╭───内功信息────────────────────────────────╮
│雪山内功(xueshan-neigong)                 ★★★★★   -  11675/ 11675(11675) │
├───其他信息────────────┬───────────────────┤
│【走火入魔】 0.00%                    │【极限内力】 11675                    │
│【恢复效率】 829.00%                  │【精纯程度】 100.00%                  │
│【压缩内力】 无                       │【内视加成】 无                       │
╰───────────────────┴──────────北大侠客行────╯
2024-03-26 12:15:53 INPUT: hp -neili（多种内功）
╭───内功信息────────────────────────────────╮
│北冥神功(beiming-shengong)                ★★★☆     -   8385/  8385(9157)  │
│逍遥派内功(xiaoyao-neigong)               ★★★★☆   -   2789/  2889(4710)  │
├───其他信息────────────┬───────────────────┤
│【走火入魔】 0.00%                    │【极限内力】 12347                    │
│【恢复效率】 471.00%                  │【精纯程度】 100.00%                  │
│【压缩内力】 无                       │【内视加成】 无                       │
╰───────────────────┴──────────北大侠客行────╯
*/

#alias {char.hp.parse.hp-neili} {
    #class char-hp-parse-hp-neili open;

    #var char[HP][内力上限] {1};

    #action {^│%S(%S) %s %S %s - %s %d/%s%d(%d{|\)}%s│{|ID=char/hp-neili}$} {
        #local name     {@str.Trim{%%1}};
        #local id       {@str.Trim{%%2}};
        #local stars    {@str.Trim{%%4}};
        #local current  {@str.Trim{%%7}};
        #local max      {@str.Trim{%%9}};
        #local limit    {@str.Trim{%%10}};
        #local line     {%%99};

        #if { "$line" == "%c│%c\e[42;1m%*" } {
            #local name {$char[Skills][基本内功][jifa-to]};
            #var char[HP][当前内力] {$current};
            #var char[HP][最大内力] {$max};
            #var char[HP][内力上限] {$limit};
        };

        #if { "$char[Skills][$name]" != "" } {
            #var char[Skills][$name][neili]         {$current};
            #var char[Skills][$name][max-neili]     {$max};
            #var char[Skills][$name][stars]         {$stars};
            #var char[Skills][$name][neili-limit]   {$limit};
        };
    };

    #action {~^%*【恢复效率】%*%+1..c{[0-9.]+}\%%*{|ID=char/hp-neili}$} {
        #local name {$char[Skills][基本内功][jifa-to]};
        #if { "$name" != "" } {
            #local multiple {@math.Eval{%%4 / 100}};
            #var char[Skills][$name][multiple] {$multiple};
        };
        #echo {%s} {@Beautify{%%1【恢复效率】%%2%%3@str.Left{{@str.Format{{%.2f};$multiple}     };@math.Eval{@str.Width{%%4}}} %%5}};
        #line gag;
    };

    #action {^│【走火入魔】 %*% %s│【极限内力】 %d%s │{|ID=char/hp-neili}$} {
        #var char[HP][走火入魔] {@str.Trim{%%1}};
    };

    #action {@re.TableTail{char/hp-neili}} {
        char.hp-neili.parse.done;
    };

    #alias {char.hp-neili.parse.done} {
        #local __unused {%%0};
        #class char-hp-parse-hp-neili kill;
        #class char.GetHP kill;
        event.DelayEmit char/hpneili;
    };

    event.ClassHandleOnce GA {char.hp-neili} {char} {char.hp-neili.parse.done};

    #class char-hp-parse-hp-neili close;
};

#nop hpbrief 格式：
#nop 第一行: 经验，潜能，最大内力，当前内力，最大精力，当前精力
#nop 第二行: 最大气血，有效气血，当前气血，最大精神，有效精神，当前精神
#nop 第三行: 真气，真元，食物，饮水，是否战斗，是否busy
#nop #69407,853,992,992,844,1398
#nop #771,776,776,397,397,397
#nop #0,0,30,43
#nop;

#nop 第一行: 经验，潜能，最大内力，当前内力，最大精力，当前精力;
#nop 第二行: 最大气血，有效气血，当前气血，最大精神，有效精神，当前精神;
#action {^{|>|> }#%1,%2,%3,%4,%5,%6$} {
    #if { "${char.parsingHP}" == "" } {
        #var char[HP][经验显示] {%1};
        #var char[HP][经验]     {@char.hp.expandBigNumber{%1}};
        #var char[HP][潜能显示] {%2};
        #var char[HP][潜能]     {@char.hp.expandBigNumber{%2}};
        #var char[HP][最大内力] {@char.hp.expandBigNumber{%3}};
        #var char[HP][当前内力] {@char.hp.expandBigNumber{%4}};
        #var char[HP][最大精力] {@char.hp.expandBigNumber{%5}};
        #var char[HP][当前精力] {@char.hp.expandBigNumber{%6}};

        speedo.Set {经验}       {$char[HP][经验]}       {true} {10};
        speedo.Set {潜能}       {$char[HP][潜能]}       {true} {10};
        speedo.Set {当前内力}   {$char[HP][当前内力]}   {true} {10};
        speedo.Set {当前精力}   {$char[HP][当前精力]}   {true} {10};

        #math char[HP][内力百分比] { $char[HP][当前内力] * 50 / $char[HP][最大内力] };
        #math char[HP][精力百分比] { $char[HP][当前精力] * 50 / $char[HP][最大精力] };

        #var char.parsingHP     {true};
        #line gag;
    };
    #else {
        #var char[HP][最大气血] {@char.hp.expandBigNumber{%1}};
        #var char[HP][有效气血] {@char.hp.expandBigNumber{%2}};
        #var char[HP][当前气血] {@char.hp.expandBigNumber{%3}};
        #var char[HP][最大精神] {@char.hp.expandBigNumber{%4}};
        #var char[HP][有效精神] {@char.hp.expandBigNumber{%5}};
        #var char[HP][当前精神] {@char.hp.expandBigNumber{%6}};

        speedo.Set {当前气血} {$char[HP][当前气血]} {true} {10};
        speedo.Set {当前精神} {$char[HP][当前精神]} {true} {10};

        #math char[HP][精神百分比] { $char[HP][当前精神] * 100 / $char[HP][最大精神] };
        #math char[HP][气血百分比] { $char[HP][当前气血] * 100 / $char[HP][最大气血] };
        #math char[HP][气血健康度] { $char[HP][有效气血] * 100 / $char[HP][最大气血] };
        #math char[HP][精神健康度] { $char[HP][有效精神] * 100 / $char[HP][最大精神] };

        #unvar char.parsingHP;
        #line gag;
    };
} {2.1};

#nop 第三行: 真气，真元，食物，饮水;
#action {^#%1,%2,%3,%4,{0|1},{0|1}$} {
    #var char[HP][当前真气]  {@char.hp.expandBigNumber{%1}};
    #var char[HP][当前真元]  {@char.hp.expandBigNumber{%2}};
    #var char[HP][食物]      {@char.hp.expandBigNumber{%3}};
    #var char[HP][饮水]      {@char.hp.expandBigNumber{%4}};

    speedo.Set {当前真气}   {$char[HP][当前真气]}   {true} {10};
    speedo.Set {食物}       {$char[HP][食物]}       {true} {10};
    speedo.Set {饮水}       {$char[HP][饮水]}       {true} {10};

    #if { "%5" == "1" } {
        char.set-flag 战斗中 true false;
    };
    #else {
        char.set-flag 战斗中 false false;
    };

    #if { "%6" == "1" } {
        char.set-flag 忙 true false;
    };
    #else {
        char.set-flag 忙 false false;
    };

    event.Emit char/hpbrief;

    #unvar char.parsingHP;

    char.HPSummarize 自动;

    #line gag;
} {2.0};

///=== {
// ## char.HPSummarize [<总是|自动>]
//    显示〔HP摘要〕提示条。
//
//    注意 HP 摘要提示条并不一定总是会显示，实际上会受到变量 char.HPSummarize.Echo 的控制。
//    char.HPSummarize.Echo 可以在 ui-settings.tin 配置中进行修改，它有三种选择: 从不、自动、总是。
//      - 从不: 无论如何都不会显示 HP 摘要。
//      - 总是: 只要有 GMCP.Status 事件则必然显示。
//      - 自动: 只有 #var gmcp-name-map[HP主要] 里的数值发生变化时才会显示。
//
//    可选的参数用来说明要进行何种程度的显示。
//      - 总是: 只有 char.HPSummarize.Echo 设置为「总是」时，才会显示。
//      - 自动: 不论 char.HPSummarize.Echo 设置为「总是」还是「自动」，都会显示。
//      - 如果省略该参数，则不论 char.HPSummarize.Echo 如何设置，都会显示。
//
//    HP 摘要被设计成了响应式布局的，它会根据屏幕的宽度，自动隐藏相对次要的数据，确保最终显示不会折行。
//
//    下面是 HP 摘要的全部字段说明：
//      - HP摘要: HP摘要是个固定的头部，但整个HP摘要条的颜色会根据 ID 的当前状态有不同的表示，并可通过 char.HPSummarize.Theme 进行定制：
//          - 平常（不忙）: 显示样式：$char.HPSummarize.Theme[背景][平常]$char.HPSummarize.Theme[前景][平常]〔HP摘要〕<299>
//          - 忙（非战斗）: 显示样式：$char.HPSummarize.Theme[背景][正忙]$char.HPSummarize.Theme[前景][正忙]〔HP摘要〕<299>
//          - 忙（战斗中）: 显示样式：$char.HPSummarize.Theme[背景][战忙]$char.HPSummarize.Theme[前景][战忙]〔HP摘要〕<299>
//          - 战斗（一般）: 显示样式：$char.HPSummarize.Theme[背景][战斗]$char.HPSummarize.Theme[前景][战斗]〔HP摘要〕<299>
//          - 战斗（安全）: 显示样式：$char.HPSummarize.Theme[背景][战安]$char.HPSummarize.Theme[前景][战安]〔HP摘要〕<299>
//          - 战斗（危险）: 显示样式：$char.HPSummarize.Theme[背景][战危]$char.HPSummarize.Theme[前景][战危]〔HP摘要〕<299>
//          - 战斗（危急）: 显示样式：$char.HPSummarize.Theme[背景][危急]$char.HPSummarize.Theme[前景][危急]〔HP摘要〕<299>
//          - 其中战斗状态下的「安全」、「危险」、「危急」的判断标准分别为
//              - 安全: 气血百分比 > 80% 并且精神百分比 > 95%
//              - 危险: 气血百分比 < 30% 或者精神百分比 < 70%
//              - 危急: 危险并且被 busy
//      - 气血: 由三个数组成，显示样式为：气血百分比(每秒气血变化)/气血健康度
//          - 气血百分比: 展示为当前气血占最大气血的比例，注意这里并没有采用有效气血。
//          - 每秒气血变化: 正数展示为绿色，负数展示为红色，如果没有变化，则自动隐藏。
//          - 气血健康度: 展示为有效气血占最大气血的比例。
//      - 内力: 由两个数组成，显示样式为：内力百分比(每秒内力变化)
//          - 内力百分比: 以最大内力的两倍为百分之百展示。
//          - 每秒内力变化: 正数展示为绿色，负数展示为红色，如果没有变化，则自动隐藏。
//      - 回气: 由两个数组成，显示样式为为：气血恢复/气血治疗
//          - 气血恢复: 展示为每分钟可以恢复的最大血量的比例（以百分比形式）
//          - 气血治疗: 展示为每分钟可以治疗的最大血量的比例（以百分比形式）
//      - 回精: 由两个数组成，显示样式为为：精神恢复/精神治疗
//          - 精神恢复: 展示为每分钟可以恢复的最大精神的比例（以百分比形式）
//          - 精神治疗: 展示为每分钟可以治疗的最大精神的比例（以百分比形式）
//      - 精神: 由三个数组成，显示样式为为：精神百分比(每秒精神变化)/精神健康度
//          - 精神百分比: 展示为当前精神占最大精神的比例，注意这里并没有采用有效精神。
//          - 每秒精神变化: 正数展示为绿色，负数展示为红色，如果没有变化，则自动隐藏。
//          - 精神健康度: 展示为有效精神占最大精神的比例。
//      - 精力: 由两个数组成，显示样式为：精力百分比(每秒精力变化)
//          - 精力百分比: 以最大精力的两倍为百分之百展示。
//          - 每秒精力变化: 正数展示为绿色，负数展示为红色，如果没有变化，则自动隐藏。
//      - 食水: 由四个数组成，显示样式为：当前食物/当前饮水(每分钟食物变化/每分钟饮水变化)
//      - 战斗标志: 如果角色处于战斗状态，则显示「战」。
//      - 气势: 如果在战斗中捕获到气势数据，则会在「战」标志后，展示当前气势。
//      - 安危标志: 战斗状态下，会自动根据 ID 状态，显示「安」或「危」标志。
//      - 忙标志: 如果角色处于忙状态，则显示「忙」。
// };
#alias {char.HPSummarize} {
    #local level {@default{%1;强制}};

    #if { "$level" != "强制" } {
        #if { @option.IsEnable{HPSummarize.Pause} } {
            #local time {@option.Get{HPSummarize.PauseTime}};
            #if { $time > @time.Now{} } {
                #return;
            };
            #elseif { $time > 0 } {
                okLog HP 摘要抑制时间已结束，现已重新开启。;
                option.Toggle HPSummarize.Pause;
                option.Set HPSummarize.PauseTime {0};
            };
        };

        #if { "$char.HPSummarize.Echo" == "从不" } {
            #return;
        };

        #if { "$char.HPSummarize.Echo" == "自动" && "$level" != "自动" } {
            #return;
        };
    };

    #local head         {};
    #local tail         {};
    #local safety       {};
    #local labelColor   {};
    #local width        {@prompt.ScreenWidth{}};

    #if { $char[HP][气血百分比] < 30 || $char[HP][精神百分比] < 70 } {
        #local safety {危险};
    };
    #elseif { $char[HP][气血百分比] > 80 && $char[HP][精神百分比] > 95 } {
        #local safety {安全};
    };

    #if { "$char[HP][战斗中]" == "true" } {
        #local labelColor {<188>};
    };

    #local theme {@default{{$char.HPSummarize.Theme};{
        {前景} { {平常}{<168>} {战斗}{<118>}  {战安}{<128>}  {战危}{<118>}  {战忙}{<138>}  {危急}{<158>}  {正忙}{<138>}  }
        {背景} { {平常}{<099>} {战斗}{<B00A>} {战安}{<B040>} {战危}{<B600>} {战忙}{<B808>} {危急}{<BA00>} {正忙}{<B330>} }
    }}};

    #switch {"$char[HP][战斗中]/$char[HP][忙]/$safety"} {
        #case {"false/false/%*"} {
            #local head    {$theme[背景][平常]$theme[前景][平常]};
            #local tail     {};
        };
        #case {"false/true/%*"} {
            #local head    {$theme[背景][正忙]$theme[前景][正忙]};
            #local tail     { $theme[前景][正忙]忙<298>};
        };
        #case {"true/false/"} {
            #local head    {$theme[背景][战斗]$theme[前景][战斗]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势])};
        };
        #case {"true/true/"} {
            #local head    {$theme[背景][战忙]$theme[前景][战忙]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势]) $theme[前景][战忙]忙<298>};
        };
        #case {"true/false/安全"} {
            #local head    {$theme[背景][战安]$theme[前景][战安]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势]) $theme[前景][战安]安<298>};
        };
        #case {"true/true/安全"} {
            #local head    {$theme[背景][战忙]$theme[前景][战忙]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势]) $theme[前景][战安]安 $theme[前景][战忙]忙<298>};
        };
        #case {"true/false/危险"} {
            #local head    {$theme[背景][战危]$theme[前景][战危]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势]) $theme[前景][战危]危<298>};
        };
        #case {"true/true/危险"} {
            #local head    {$theme[背景][危急]$theme[前景][危急]};
            #local tail     { $theme[前景][战斗]战($char[HP][气势]) $theme[前景][战危]危 $theme[前景][战忙]忙<298>};
        };
    };

    #local 每秒气血变化 {@speedo.GetSpeed{当前气血}};
    #if { ${每秒气血变化} > 0 } {
        #local 每秒气血变化 {(<128>${每秒气血变化}<298>)};
    };
    #elseif { ${每秒气血变化} < 0 } {
        #local 每秒气血变化 {(<118>${每秒气血变化}<298>)};
    };
    #else {
        #local 每秒气血变化 {};
    };

    #local label {气血};
    #if { $char[HP][食物] <= 0 || $char[HP][饮水] <= 0 } {
        #local label {<118>气血};
    };

    #local 气血 {};
    #if { !@char.InTuna{} || $width >= 70 } {
        #format 气血 {$labelColor$label<298>: %s%s/%s}
            {@char.hp.colorit{$char[HP][气血百分比]}} {${每秒气血变化}}
            {@char.hp.colorit{$char[HP][气血健康度]}};
    };

    #local 内力 {};
    #if { @char.InCombat{} || $width >= 80 || ($width >= 50 && !@char.InTuna{}) } {
        #local 每秒内力变化 {@speedo.GetSpeed{当前内力}};
        #if { ${每秒内力变化} > 0 } {
            #local 每秒内力变化 {(<128>${每秒内力变化}<298>)};
        };
        #elseif { ${每秒内力变化} < 0 } {
            #local 每秒内力变化 {(<118>${每秒内力变化}<298>)};
        };
        #else {
            #local 每秒内力变化 {};
        };
        #format 内力 { $labelColor内力: %s%s} {@char.hp.colorit{$char[HP][内力百分比]}} {${每秒内力变化}};
    };

    #local 精神 {};
    #if { @char.InCombat{} || @char.InTuna{} || $width >= 80 || $char[HP][精神百分比] < 70 || $char[HP][精神健康度] < 100 } {
        #local 每秒精神变化 {@speedo.GetSpeed{当前精神}};
        #if { ${每秒精神变化} > 0 } {
            #local 每秒精神变化 {(<128>${每秒精神变化}<298>)};
        };
        #elseif { ${每秒精神变化} < 0 } {
            #local 每秒精神变化 {(<118>${每秒精神变化}<298>)};
        };
        #else {
            #local 每秒精神变化 {};
        };
        #local label {精神};
        #if { $char[HP][食物] <= 0 || $char[HP][饮水] <= 0 } {
            #local label {<118>精神};
        };
        #format 精神 { $labelColor$label<298>: %s%s/%s}
            {@char.hp.colorit{$char[HP][精神百分比]}} {${每秒精神变化}}
            {@char.hp.colorit{$char[HP][精神健康度]}};
    };

    #local 回气 {};
    #if { (@char.InCombat{} || $width >= 80 && !@char.IsBusy{}) && ($char[HP][气血百分比] < 100 || $char[HP][气血健康度] < 100) } {
        #nop 气血恢复的数值展示为每分钟可以恢复的最大血量的倍数（以百分比形式）;
        #local {气血恢复} {@math.Int{@math.Eval{$char[STATUS][气血恢复] * 100 * 60 / $char[HP][最大气血]}}};
        #nop 气血治疗的数值展示为每分钟可以治疗的最大血量的倍数（以百分比形式）;
        #local {气血治疗} {@math.Int{@math.Eval{$char[STATUS][气血治疗] * 100 * 60 / $char[HP][最大气血]}}};
        #local label {回气};
        #if { !@char.IsBusy{} && $char[HP][食物] > 0 && $char[HP][饮水] > 0 && ($char[HP][气血百分比] < 100 || $char[HP][气血健康度] < 100) } {
            #local label {<128><588>回气\e[25m};
        };
        #format {回气} { $labelColor$label: %s/%s} {@char.hp.colorit{${气血恢复}}} {@char.hp.colorit{${气血治疗}}};
    };

    #local 回精 {};
    #if { (@char.InCombat{} || $width >= 80 && !@char.IsBusy{}) && ($char[HP][精神百分比] < 100 || $char[HP][精神健康度] < 100) } {
        #nop 精神恢复的数值展示为每分钟可以恢复的最大精神的倍数（以百分比形式）;
        #local {精神恢复} {@math.Int{@math.Eval{$char[STATUS][精神恢复] * 100 * 60 / $char[HP][最大精神]}}};
        #nop 精神治疗的数值展示为每分钟可以治疗的最大精神的倍数（以百分比形式）;
        #local {精神治疗} {@math.Int{@math.Eval{$char[STATUS][精神治疗] * 100 * 60 / $char[HP][最大精神]}}};
        #local label {回精};
        #if { !@char.IsBusy{} && $char[HP][食物] > 0 && $char[HP][饮水] > 0 && ($char[HP][精神百分比] < 100 || $char[HP][精神健康度] < 100) } {
            #local label {<128><588>回精\e[25m};
        };
        #format {回精} { $labelColor$label: %s/%s} {@char.hp.colorit{${精神恢复}}} {@char.hp.colorit{${精神治疗}}};
    };

    #local 精力 {};
    #if { @char.InTuna{} || $width >= 120 || $char[HP][精力百分比] < 50 } {
        #local 每秒精力变化 {@speedo.GetSpeed{当前精力}};
        #if { ${每秒精力变化} > 0 } {
            #local 每秒精力变化 {(<128>${每秒精力变化}<298>)};
        };
        #elseif { ${每秒精力变化} < 0 } {
            #local 每秒精力变化 {(<118>${每秒精力变化}<298>)};
        };
        #else {
            #local 每秒精力变化 {};
        };
        #format 精力 { $labelColor精力: %s%s} {@char.hp.colorit{$char[HP][精力百分比]}} {${每秒精力变化}};
    };

    #local 食水 {};
    #if { $width >= 110 } {
        #local label {食水};
        #if { $char[HP][食物] <= 0 || $char[HP][饮水] <= 0 } {
            #local label {<118><588>食水\e[25m<288>};
        };
        #if { @char.InCombat{} } {
            #format {食水} { $label: %s/%s} {$char[HP][食物]} {$char[HP][饮水]};
        };
        #else {
            #format {食水} { $label: %s/%s(%s/%s)}
                    {$char[HP][食物]} {$char[HP][饮水]}
                    {@speedo.GetSpeed{食物;60}} {@speedo.GetSpeed{饮水;60}};
        };
    };

    #local summarize {<099>$head〔HP摘要〕<298>${气血}${内力}${回气}${精神}${回精}${精力}${食水}$tail<099>};
    #showme $summarize;
};

option.Define {HPSummarize.Pause}       {Bool}      {是否暂停 HP 摘要显示}      {false};
option.Define {HPSummarize.PauseTime}   {Time}      {暂停显示 HP 摘要截止时间}  {0};
event.Handle {option/changed} {opt/HPSummarize.Pause/pkuxkx} {$MODULE} {char.HPSummarize.onTogglePause};

#alias {char.HPSummarize.onTogglePause} {
    #if { @option.IsEnable{HPSummarize.Pause} } {
        #local time {@math.Eval{@time.Now{} + 86400 * 7}};
        warnLog 你已选择临时抑制 HP 摘要。在 @time.Format{$time} 之前，你将不会再看到 HP 摘要。;
        warnLog HP 摘要是 PaoTin++ 非常有特色的功能，几乎每个用户都喜欢它。;
        warnLog 希望那时的你能够以更加开放的心态来迎接它。;
        option.Set HPSummarize.PauseTime {$time};
    };
    #else {
        okLog HP 摘要是 PaoTin++ 非常有特色的功能，几乎每个用户都喜欢它。欢迎体验。;
        option.Set HPSummarize.PauseTime {0};
    };
};

#func {char.hp.expandBigNumber} {
    #local number {%1};
    #replace number {K} {*1000};
    #replace number {M} {*1000000};
    #math number {$number};
    #return $number;
};

#func {char.hp.colorit} {
    #local percent {@math.Int{@defaultNum{%1;0}}};
    #local color {@default{{$char.HPSummarize.Theme[色卡]};{<218>;15;<118>;30;<238>;60;<138>;90;<128>;101;<168>}}};
    #return {@util.Grade{$percent;$color}$percent%<298>};
};

#alias {char.GetHP} {
    #class char.GetHP open;

    #nop ╭───个人状态────────────┬───────────────────╮;
    #action {@re.TableHeader{个人状态}} {
        #class char.GetHP kill;
        char.hp.parse.hp;
    };

    #nop ╭───内功信息────────────────────────────────╮;
    #action {@re.TableHeader{内功信息}} {
        #class char.GetHP kill;
        char.hp.parse.hp-neili;
    };

    #action {~^%c【状态】%*\e[2;37;0m{?:|、(.*)\x1b\[2;37;0m}%s%c$} {
        #var char[STATUS][健康状态] {%%2};
        #var char[STATUS][持续效果] {%%3};
        event.DelayEmit char/status;
        #class char.GetHP kill;
    } {4};

    #action {^你用HP太频繁了，请尽量使用hpbrief命令，节约系统资源，谢谢。$} {
        #class char.GetHP kill;
    };

    #class char.GetHP close;

    xtt.Send {hp %0};
};

#alias {char.GetHP2} {
    #class char.GetHP2 open;
    #gag {^你关闭了GMCP:Status频道。$};
    #gag {^你打开了GMCP:Status频道。$};
    #class char.GetHP2 close;
    tune gmcp status off;
    hpbrief;
    tune gmcp status on;
    sync.Wait {#class char.GetHP2 kill};
};

#alias {hp} {
    #if { "%0" == "{|-neili|-status}" } {
        char.GetHP %0;
    };
    #else {
        xtt.Send {hp %0};
    };
};

///=== {
// ## char.MarkBusy <布尔值>
//    设置角色的忙状态。
// };
#alias {char.MarkBusy} {char.set-flag 忙 true};

///=== {
// ## char.UnmarkBusy <布尔值>
//    取消角色的忙状态。
// };
#alias {char.UnmarkBusy} {char.set-flag 忙 false};

///=== {
// ## char.MarkFight <布尔值>
//    设置角色的战斗状态。
// };
#alias {char.MarkFight} {char.set-flag 战斗中 true};

///=== {
// ## char.UnmarkFight <布尔值>
//    取消角色的战斗状态。
// };
#alias {char.UnmarkFight} {char.set-flag 战斗中 false};

#alias {char.set-flag} {
    #local flag  {%1};
    #local value {%2};
    #local summ  {@default{%3;true}};

    #if { "$char[HP][$flag]" == "$value" } {
        #return;
    };

    #var char[HP][$flag] {$value};

    #switch {"$flag/$value"} {
        #case {"忙/true"}       {event.Emit char/busy};
        #case {"忙/false"}      {event.Emit char/nobusy};
        #case {"战斗中/true"}   {event.Emit char/fight};
        #case {"战斗中/false"}  {event.Emit char/nofight};
    };

    event.Emit char/hpbrief;

    #if { "$summ" == "true" } {
        char.HPSummarize 自动;
    };
};

///=== {
// #@ char.IsBusy
//    如果角色正忙，则返回真，否则返回假。无参数。
// };
#func {char.IsBusy} {
    #if { "$char[HP][忙]" == "true" } {
        #return 1;
    };
    #else {
        #return 0;
    };
};

///=== {
// #@ char.IsIdle
//    如果角色不忙，则返回真，否则返回假。无参数。
// };
#func {char.IsIdle} {
    #if { "$char[HP][忙]" == "false" } {
        #return 1;
    };
    #else {
        #return 0;
    };
};

///=== {
// #@ char.InDazuo
//    如果角色正在打坐，则返回真，否则返回假。无参数。
// };
#func {char.InDazuo} {
    #if { @char.IsBusy{} && "@ga.LastCmd{}" == "{exercise|dazuo} %*" } {
        #return 1;
    };
    #else {
        #return 0;
    };
};

///=== {
// #@ char.InTuna
//    如果角色正在吐纳，则返回真，否则返回假。无参数。
// };
#func {char.InTuna} {
    #if { @char.IsBusy{} && "@ga.LastCmd{}" == "{respirate|tuna} %*" } {
        #return 1;
    };
    #else {
        #return 0;
    };
};

///=== {
// #@ char.InCombat
//    如果角色正处于战斗中，则返回真，否则返回假。无参数。
// };
#func {char.InCombat} {
    #if { "$char[HP][战斗中]" == "true" } {
        #return 1;
    };
    #else {
        #return 0;
    };
};

#action {^虽然藏而不发，你仍在不断积蓄攻势。(气势：%d%)$E}              {char.hp.set-qishi %1};
#action {^你在攻击中不断积蓄攻势。(气势：%d%)$E}                        {char.hp.set-qishi %1};
#action {^你蓄足攻势，在战斗中发出绝招「%*」。(气势：%d%)$E}            {char.hp.set-qishi %2};
#action {^你蓄势不足，目前只积累了%d%气势。$E}                          {char.hp.set-qishi %1};
#action {^出招太猛，招式用老，你的气势降低了。(气势：%d%)$E}            {char.hp.set-qishi %1};
#action {^你暂缓了攻势。(气势：%d%)$E}                                  {char.hp.set-qishi %1};
#action {^你运用了「纤云步法」，躲闪成功之后信心倍增。(气势：%d%)$E}    {char.hp.set-qishi %1};
#action {^你逐步从之前战斗的紧张气氛中平缓下来。(气势：%d%)$E}          {#var char[HP][气势] {%1}};
#action {^经过一段时间后，你终于完全从紧张地战斗氛围中解脱出来。$E}     {#var char[HP][气势] {0}};

#alias {char.hp.set-qishi} {
    #local qishi {%1};
    #var char[HP][气势] {$qishi};
    char.set-flag 战斗中 true;
};

///=== {
// ## char.UncolorEnemy
//    擦掉敌人的血量告警提示的颜色，防止麻痹眼睛。
// };
#alias {char.UncolorEnemy} {
    #class char.UncolorEnemy open;

    #nop 气血上限组;
    #nop 100;   #sub {^( %+2..5u看起来气血充盈，并没有受伤。}                       {( %%1气血充盈};
    #nop 95+;   #sub {^( %+2..5u似乎受了点轻伤，不过光从外表看不大出来。}           {( %%1不似受伤};
    #nop 90+;   #sub {^( %+2..5u看起来可能受了点轻伤。}                             {( %%1略有轻伤};
    #nop 80+;   #sub {^( %+2..5u受了几处伤，不过似乎并不碍事。}                     {( %%1不大碍事};
    #nop 60+;   #sub {^( %+2..5u受伤不轻，看起来状况并不太好。}                     {( %%1受伤不轻};
    #nop 40+;   #sub {^( %+2..5u气息粗重，动作开始散乱，看来所受的伤著实不轻。}     {( %%1着实不轻};
    #nop 30+;   #sub {^( %+2..5u已经伤痕累累，正在勉力支撑著不倒下去。}             {( %%1伤痕累累};
    #nop 20+;   #sub {^( %+2..5u受了相当重的伤，只怕会有生命危险。}                 {( %%1生命危险};
    #nop 10+;   #sub {^( %+2..5u伤重之下已经难以支撑，眼看就要倒在地上。}           {( %%1伤重难支};
    #nop 5+;    #sub {^( %+2..5u受伤过重，已经奄奄一息，命在旦夕了。}               {( %%1奄奄一息};
    #nop 5-;    #sub {^( %+2..5u受伤过重，已经有如风中残烛，随时都可能断气。}       {( %%1随时断气};

    #nop 气血组;
    #nop 100;   #sub {^( %+2..5u看起来充满活力，一点也不累。}                       {( %%1充满活力};
    #nop 95+;   #sub {^( %+2..5u似乎有些疲惫，但是仍然十分有活力。}                 {( %%1有些疲惫};
    #nop 90+;   #sub {^( %+2..5u看起来可能有些累了。}                               {( %%1有些累了};
    #nop 80+;   #sub {^( %+2..5u动作似乎开始有点不太灵光，但是仍然有条不紊。}       {( %%1不太灵光};
    #nop 60+;   #sub {^( %+2..5u气喘嘘嘘，看起来状况并不太好。}                     {( %%1气喘吁吁};
    #nop 40+;   #sub {^( %+2..5u似乎十分疲惫，看来需要好好休息了。}                 {( %%1十分疲惫};
    #nop 30+;   #sub {^( %+2..5u已经一副头重脚轻的模样，正在勉力支撑著不倒下去。}   {( %%1头重脚轻};
    #nop 20+;   #sub {^( %+2..5u看起来已经力不从心了。}                             {( %%1力不从心};
    #nop 10+;   #sub {^( %+2..5u摇头晃脑、歪歪斜斜地站都站不稳，眼看就要倒在地上。} {( %%1摇头晃脑};
    #nop 10-;   #sub {^( %+2..5u已经陷入半昏迷状态，随时都可能摔倒晕去。}           {( %%1随时晕倒};

    #class char.UncolorEnemy close;
};

#action {^你的内力增加了！！$E} {
    #local name {$char[Skills][基本内功][jifa-to]};
    #local limit {$char[Skills][$name][neili-limit]};
    #if { "$limit" != "" } {
        #local limit { / $limit};
    };
    #else {
        hp -neili;
    };
    fullskLog <139>$name<299> 的内力提升！当前进度: @math.Eval{$char[HP][最大内力] + 1}$limit;
} {9.1};

#action {^你的精力上限增加了！！$E} {
    #local limit {@math.Eval{@char.SkillJifaLevel{基本内功} * 10}};
    fullskLog <139>你的精力上限增加了！！<299> 当前进度: @math.Eval{$char[HP][最大精力] + 1} / $limit;
} {9.1};