#nop vim: set filetype=tt:;

/*
本文件属于 PaoTin++ 的一部分
===========
PaoTin++ © 2020~2023 的所有版权均由担子炮(dzp <danzipao@gmail.com>) 享有并保留一切法律权利
你可以在遵照 GPLv3 协议的基础之上使用、修改及重新分发本程序。
===========
*/

#var basic_char_special[META] {
    {NAME}      {特技数据管理}
    {DESC}      {全生命周期维护 special/sp 命令结果。}
    {AUTHOR}    {担子炮}
    {NOTE}      {本文件属于 PaoTin++ 的一部分}
};

VAR {角色特技列表，表格} {char.Special} {};

#func {basic_char_special.Init} {
    #delay {char.special.Init} {special} 1;

    #return true;
};

/*
2025-03-04 00:13:15 INPUT: sp
╭───特技列表─────────────────────┬─────────╮
│      │特技                                            │级别              │
├───┼────────────────────────┼─────────┤
│*     │身轻如燕(agile)                                 │●●              │
│      │金蝉脱壳(chainless)                             │●                │
│*     │铜皮铁骨(ironskin)                              │●                │
│*     │饕餮之力(greedy)                                │●                │
├───┴────────────────────────┴─────────┤
│特技积分6800点，最多可同时激发3个特技。                                     │
╰─────────────────────────────北大侠客行────╯
*/

#action {@re.TableHeader{特技列表}} {
    #class char-special-parser open;

    #var char.Special {};

    #action {^│{|\*} %s │%S(%S) %s │%S %s │{|ID=char/special}$} {
        #local enable   {%%1};
        #local name     {%%3};
        #local id       {%%4};
        #local level    {@str.Len{%%6}};

        #if { "$enable" == "*" } {
            #local enable {true};
        };
        #else {
            #local enable {false};
        };

        #var char.Special[$name] {
            {id}{$id}
            {name}{$name}
            {enable}{$enable}
            {level}{$level}
        };
    };

    #action {^│特技积分%d点，最多可同时激发%d个特技。 %s │{|ID=char/special}$} {
        #var char.Special[META][剩余积分] {%%1};
        #var char.Special[META][特技槽位] {%%2};
        #delay 0 {okLog 角色特技数据已记录。};
        #class char-special-parser kill;
    };

    ga.ClassWait {#class char-special-parser kill};

    #class char-special-parser close;
};

#alias {char.Special} {
    #local gag  {%1};
    #local args {%2};

    #if { "$args" != "" } {
        xtt.Send {special $args};
        #return;
    };

    #class char.Special open;

    #action {^你还未成年，不能使用特殊技能。{|ID=char/special}$} {
        #var char.Special {};
        #class char.Special kill;
    };

    #action {^你现在什么特技都不会，你共拥有特技积分%d点，你最多可以同时激发%d个特技。} {
        #var char.Special {};
        #var char.Special[META][剩余积分] {%%1};
        #var char.Special[META][特技槽位] {%%2};
        #class char.Special kill;
    };

    #if { "$gag" == "gag" } {
        #gag {^%*{|ID=char/special}$};
    };

    #class char.Special close;

    xtt.Send {special};
};

#alias {special_gag}    {char.Special gag {%0}};
#alias {special}        {char.Special nogag {%0}};
#alias {sp}             {char.Special nogag {%0}};

#action {^你把%*加入了你的激发特技列表。$E} {
    #local name {%1};
    #if { "$char.Special[$name]" == "" } {
        char.Special gag;
    };
    #else {
        #var char.Special[$name][enable] {true};
    };
};

#action {^你把%*从你的激发特技列表中移除。$E} {
    #local name {%1};
    #if { "$char.Special[$name]" == "" } {
        char.Special gag;
    };
    #else {
        #var char.Special[$name][enable] {false};
    };
};