feat(shortcut): 一些杂项触发

plugins/shortcut.tin

@@ -0,0 +1,214 @@
+#alias N {n;nd;nu};
+#alias E {e;ed;eu};
+#alias W {w;wd;wu};
+#alias S {s;sd;su};
+#alias SW {sw;S;W};
+#alias SE {se;S;E};
+#alias NE {ne;N;E};
+#alias NW {nw;N;W};
+
+#action {^== 未完继续 %*% == (q 离开，b 前一页，其他继续下一页)$E} {#cr};
+
+#alias jd jianding;
+#alias {beep} {#echo {\a\}};
+
+#event {TIME 08:55} {#echo <120>准备保卫！！！<070>};
+#event {TIME 15:55} {#echo <120>准备保卫！！！<070>};
+#event {TIME 20:25} {#echo <120>准备保卫！！！<070>};
+#event {TIME 20:55} {#echo <120>准备保卫！！！<070>};
+
+#event {TIME 07:55} {#echo <120>准备答题！！！<070>};
+#event {TIME 19:55} {#echo <120>准备答题！！！<070>};
+
+#alias {cgem} {do 3 pickgem %1; combine gem; pack gem};
+
+#alias {bwcx} {
+    #local keyword {%1};
+    #if { "$keyword" == "" && "$char[档案][门派]" != "" } {
+        #local keyword {$char[档案][门派]};
+    };
+
+    #class bwcx open;
+    #high {^天下争霸第%*$keyword%*$} {light magenta};
+    #action {^开始后，自动安排好三天后的比武。$} {bwcx.return};
+    #action {^等等，系统喘气中......$}           {bwcx.retry};
+    #alias {bwcx.retry}     {#delay bwcx.retry {bwcx} 5};
+    #alias {bwcx.return}    {#class bwcx kill};
+    #class bwcx close;
+
+    #send bwcx;
+};
+
+#alias {xtt.break} {
+    #line oneshot #alias {%1} {#echo {<110>任务已暂停，请输入 %1 %s 继续运行。<070>} }
+};
+
+#alias chat-ren-song    {chat* admit $user[id]; chat* xuanwu; chat* sob $user[id]; chat* cry $user[id]; chat* cry; chat* weak};
+#alias chat-shuang      {chat* massage $user[id]; chat* shuang; chat* shuang $user[id]; chat* shuang};
+#alias chat-zb          {chat* unme $user[id]; chat* unme; chat* mark; chat* mark $user[id]; chat* bud $user[id]};
+
+#alias chat-sz {
+    chat $user[name]动作妩媚，朝你微微一笑,使出了「美人三招」！;
+    chat $user[name]使完「贵妃回眸」，想起英雄三招，意犹未尽，又出三招！;
+    chat $user[name]使完「小怜横陈」，想起自己历经劫难已是武学大家，不由得豪气干云，又出三招！;
+    chat $user[name]使完「飞燕回翔」，想起多年召蛇心得，心血来潮，自创三招！;
+    chat $user[name]一共向你使出了一十八招！;
+};
+
+#alias {i-all} {
+    #class i-all open;
+    #var i-all-old-value {@option.Set{EchoCommand;false}};
+    #action {^你身上id为%*的东西有下面这些：$} {#line gag};
+    #action {^你身上没有id为%*的东西。$} {#line gag};
+    #action {^{>|}%s$} {#line gag};
+    #class i-all close;
+    #delay 1 { option.Set EchoCommand $i-all-old-value; #class i-all kill};
+
+    i sword;
+    i blade;
+    i dagger;
+    i staff;
+    i needle;
+    i flute;
+
+    i ring;
+    i necklace;
+
+    i armor;
+    i cloth;
+    i boots;
+    i shield;
+    i surcoat;
+    i wrists;
+    i hands;
+    i head;
+    i waist;
+
+    i armet;
+    i bracer;
+    i cape;
+    i gauntlet;
+    i belt;
+    i mask;
+    i cuirass;
+    i pauldron;
+    i cuisse;
+};
+
+#alias {pp} {helpme; helpme find %0};
+
+#gag {向红豆打听有关『%*』的消息。$E};
+
+#action {^你掉转船头，迅速的划回到了鄱阳湖边。$E} {
+    give xiang to ren;
+} {9.999};
+
+#action {^%*给你一枚%*{☆|★|◎}%*。$E} {
+    pack gem;
+} {9.999};
+
+#alias kk {look %0; lookin %0; follow %0; killall %0};
+
+#action {^没有经过通传，任何人等不得擅闯都统治府。$E} {ask shiwei about 通传} {9.999};
+
+#alias tichun {
+    #class tichun open;
+    #action {^你目前的修为还可以再转换%%1点内力变为真气。$E} {#delay 0 {#send tichun %%1}} {9.999};
+    #class tichun close;
+    #delay 1 {#send tichun $char[HP][当前内力]};
+};
+
+#action {^你瞬间感到了危险临近，奸细就在附近！$E} {killall} {9.999};
+
+#action {^一支铜雀轻轻地落在你的面前，你可以选择下列任务系列中一组：$E} {
+    disable-all-command;
+} {9.999};
+
+#alias {disable-all-command} {
+    #class disable-all-command open;
+
+    #alias {undo-disable-all-command} {
+        #class disable-all-command kill;
+        #ignore actions off;
+        #ignore tickers off;
+        #ignore delays off;
+        #ignore events off;
+        #ignore macros off;
+    } {1.0};
+
+    #alias {^%*$E} {
+        #echo {<110>命令已被抑制（可用 <120>#send<110> 强制发送。撤销请用 <120>undo-disable-all-command<110>）: <130>%s<070>} {%%0}
+    } {1.1};
+
+    #ignore actions on;
+    #ignore tickers on;
+    #ignore delays on;
+    #ignore events on;
+    #ignore macros on;
+
+    #class disable-all-command close;
+};
+
+#action {^你一顿棍棒乱揍，看来杀手有点怕你了。$E}                   {halt;quan} {9.999};
+#action {^( 蒙面杀手似乎十分疲惫，看来需要好好休息了。)$E}          {halt;ask killer about 认输} {9.999};
+#action {^( 蒙面杀手已经陷入半昏迷状态，随时都可能摔倒晕去。)$E}    {halt;ask killer about 认输} {9.999};
+
+#alias {show-time} {
+    #local now {};
+    #format now {%t} {%Y-%m-%d %H:%M:%S};
+    #echo {NOW: %s} {$now};
+};
+
+#alias {time-it} {
+    #local now {};
+    #format now {%t} {%Y-%m-%d %H:%M:%S};
+    #echo {%s} {$now %0};
+    #line gag;
+};
+
+#gag {^%s$};
+#gag {^>%s$};
+#gag {^├{(─|┼)+}┤$};
+
+#action {$B临走之际，你忽然发现一个盒子看起来有些特殊！$E} {
+    open box;
+} {9.999};
+
+#action {^你要进入哪间储物柜？$E} {
+    enter $user[id];
+    find;
+} {9.999};
+
+#action {$B你仔细地将鹿皮袋绑在腰间。$E} {
+    put shi zi in lupi dai;
+} {9.999};
+
+#action {$B你捡起一把玉石子。$E} {
+    put shi zi in lupi dai;
+} {9.999};
+
+#action {$B你从%*搜出一把玉石子。$E} {
+    put shi zi in lupi dai;
+} {9.999};
+
+#action {◆北大侠客行总图◆$E} {
+    #class main-map open;
+    #sub {~\e[0m       } {};
+    #class main-map close;
+    #action {^最近修订时间} {
+        #class main-map kill;
+    };
+} {9.999};
+
+#action {^你因为种种原因停了下来，可以用walk继续进行。$E} {#send walk} {9.999};
+
+#alias {ttc.cm} {
+    #local option {%1};
+
+    #if { "$option" == "on" } {
+        #config {convert meta} on;
+    };
+    #else {
+        #config {convert meta} off;
+    };
+};